https://gitweb.dealii.org/ - code-gallery.git/blob

   1
   2 #GNUPLOT file to plot graphs of biomechanical brain tests in Budday et al 2017
   3 # **** cycles must be separated in the .sol file by two blank lines ****
   4 # UNITS CONSIDERED: g - mm - s
   5
   6 #To see color names:
   7 # >> show palette colornames
   8
   9 #To see line style, line width, etc.:
  10 # >> set terminal wxt enhanced dashed
  11 # >> test
  12
  13 clear
  14 set datafile separator ","
  15 set term png size 400,300 enhanced font 'Verdana,12'
  16
  17
  18 unset colorbox
  19 set style line 1  lw 1.5  lc rgb "black"   dt 1
  20 set style line 2  lw 1.5  lc rgb "blue"    dt 1
  21 set style line 3  lw 1.5  lc rgb "red"     dt 1
  22 set style line 4  lw 1.5  lc rgb "dark-turquoise"  dt 1
  23 set style line 5  lw 1.5  lc rgb "dark-red"        dt 1
  24
  25 set style line 100 lt 1  lw 1  lc rgb "gray" dt 3
  26 set style line 101 lt 1  lw 1  lc rgb "red"
  27
  28 set notitle
  29 set grid xtics ytics ls 100
  30
  31 # -------------------- PROBLEM DATA --------------------------------------------------------------------------------------
  32 #length of specimen along loading direction to compute stretch [mm]
  33 length = 5.0
  34
  35 #area of loading surface to compute reaction force [mm²]
  36 area = length * length                    #cube
  37 #area = 3.1416 * (length/2) * (length/2)  #cylinder
  38
  39 #length to compute pressure gradient [mm]
  40 radius = length/2
  41
  42 #pressure at drained boundary to compute pressure gradient [Pa]
  43 atm_pressure = 0.0
  44
  45
  46 #dynamic (shear) fluid viscosity [Pa·s]
  47 mu = 0.89e-3
  48 #effective fluid density [g/mm³]
  49 rho = 0.997e-3
  50 #kinematic fluid viscosity [mm²/s]
  51 nu = mu/rho
  52
  53 #time step to compute numerical dissipation [s]
  54 timestep = 1.0
  55
  56
  57 # -------------------- Stress vs stretch ---------------------------------------------------------------------------------
  58 stretch(x) = (length + x) / length
  59 nominal(y) =  -y / (area*1000)           #compression  [10⁻⁶ N / mm² = Pa]
  60 #nominal(y) =  y / (area)           #tension
  61
  62 set xlabel 'stretch [-]' font 'Verdana,14'
  63 set ylabel 'nominal stress [kPa]' font 'Verdana,14'
  64 unset y2label
  65 set key on box inside top left font 'Verdana,12' spacing 1.0 maxcols 1 width -0.2
  66
  67 set xrange [1.0:0.89] reverse                    #compression
  68 set yrange [0.0:5.5]
  69
  70 unset y2tics
  71 set xtics 0.02 rotate by 45 right
  72 set ytics 1.0
  73 set format x "%3.2f"
  74 set format y "%3.1f"
  75
  76 set output "brain_cube_stress-stretch-poro-COMP.png"
  77 plot 'data-for-gnuplot.sol' index 0 using (stretch($7)):(nominal($15)) every 1  with lines ls 1 title '1^{st} cycle', \
  78      'data-for-gnuplot.sol' index 1 using (stretch($7)):(nominal($15)) every 1  with lines ls 2 title '2^{nd} cycle', \
  79      'data-for-gnuplot.sol' index 2 using (stretch($7)):(nominal($15)) every 1  with lines ls 3 title '3^{rd} cycle'
  80
  81 # -------------------- Extra stress vs stretch ---------------------------------------------------------------------------------
  82 stretch(x) = (length + x) / length
  83 nominal(y) =  -y / (area*1000)           #compression  [10⁻⁶ N / mm² = Pa]
  84 #nominal(y) =  y / (area)           #tension
  85
  86 set xlabel 'stretch [-]' font 'Verdana,14'
  87 set ylabel 'solid nominal stress [kPa]' font 'Verdana,14'
  88 unset y2label
  89 set key on box inside top left font 'Verdana,12' spacing 1.0 maxcols 1 width -0.2
  90
  91 set xrange [1.0:0.89] reverse                    #compression
  92 set yrange [0.0:5.5]
  93
  94 unset y2tics
  95 set xtics 0.02 rotate by 45 right
  96 set ytics 1.0
  97 set format x "%3.2f"
  98 set format y "%3.1f"
  99
 100 set output "brain_cube_solid-stress-stretch-poro-COMP.png"
 101 plot 'data-for-gnuplot.sol' index 0 using (stretch($7)):(nominal($21)) every 1  with lines ls 1 title '1^{st} cycle', \
 102      'data-for-gnuplot.sol' index 1 using (stretch($7)):(nominal($21)) every 1  with lines ls 2 title '2^{nd} cycle', \
 103      'data-for-gnuplot.sol' index 2 using (stretch($7)):(nominal($21)) every 1  with lines ls 3 title '3^{rd} cycle'
 104
 105 # -------------------- Accumulated exiting fluid vs time  --------------------------------------------------------------------------
 106 set xrange [] noreverse
 107 set yrange [] noreverse
 108 set xtics 30 norotate nooffset
 109 set ytics 0.5
 110 set autoscale xy
 111 set format x "%3.0f"
 112 set format y "%3.1f"
 113
 114 set xlabel 'time [s]' font 'Verdana,14'
 115 set ylabel sprintf("accumulated fluid\n outside the sample [mm^3]") font 'Verdana,14'
 116
 117 unset key
 118 a=0
 119 y_axis(y) = (a=a+y*timestep,a)
 120
 121 set output "brain_cube_fluid-time-poro-COMP.png"
 122 plot 'data-for-gnuplot.sol' index 0 using ($1):(y_axis($22)) every 1  with lines ls 1 title '1^{st} cycle', \
 123      'data-for-gnuplot.sol' index 1 using ($1):(y_axis($22)) every 1  with lines ls 2 title '2^{nd} cycle', \
 124      'data-for-gnuplot.sol' index 2 using ($1):(y_axis($22)) every 1  with lines ls 3 title '3^{rd} cycle'
 125
 126 # -------------------- Accumulated exiting fluid vs reaction pressure  ---------------------------------------------------------------
 127 set xlabel 'fluid reaction pressure [kPa]' font 'Verdana,14'
 128 set ylabel sprintf("accumulated fluid\n outside the sample [mm^3]") font 'Verdana,14'
 129 set key on box outside above right font 'Verdana,12' spacing 1.0 maxcols 1 width -0.2
 130
 131 set autoscale xy
 132 set ytics 0.5
 133 set xtics 10
 134 a=0
 135 y_axis(y) = (a=a+y*timestep,a)
 136
 137 set output "brain_cube_fluid-reac_p-poro-COMP.png"
 138 plot 'data-for-gnuplot.sol' index 0 using (-($18)/1000):(y_axis($22)) every 1  with lines ls 1 title '1^{st} cycle', \
 139      'data-for-gnuplot.sol' index 1 using (-($18)/1000):(y_axis($22)) every 1  with lines ls 2 title '2^{nd} cycle', \
 140      'data-for-gnuplot.sol' index 2 using (-($18)/1000):(y_axis($22)) every 1  with lines ls 3 title '3^{rd} cycle'
 141
 142 # -------------------- Pressure and displ. vs time -------------------------------------------------------------------------
 143 set term png size 600,380 enhanced font 'Verdana,12'
 144
 145 set format x "%3.0f"
 146 set format y "%3.1f"
 147 set xtics 30 norotate nooffset
 148
 149 set xlabel 'time [s]' font 'Verdana,14'
 150 set ylabel 'displacement [mm]' font 'Verdana,14'
 151 set y2label 'pressure [kPa]' font 'Verdana,14'
 152 set ytics 0.1 nomirror
 153 set y2tics autofreq
 154 set key width -5
 155 set output "brain_cube_pres-displ-vs-time-poro-COMP.png"
 156 plot 'data-for-gnuplot.sol' using ($1):($8)/1000 every 1  with lines ls 5 axes x1y2 title 'pressure at central column', \
 157      'data-for-gnuplot.sol' using ($1):($7) every 1  with lines ls 4 axes x1y1 title 'vertical displacement of top surface'